Show Database Window after Hide

Global Const SW_HIDE = 0
Global Const SW_SHOWNORMAL = 1
Global Const SW_SHOWMINIMIZED = 2
Global Const SW_SHOWMAXIMIZED = 3

Private Declare PtrSafe Function apiShowWindow Lib "user32" Alias "ShowWindow" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long

Function fSetAccessWindow(nCmdShow As Long)

    Dim loX As Long
    Dim loForm As Form
    
    On Error Resume Next
    Set loForm = Screen.ActiveForm
    
    If Err <> 0 Then
        loX = apiShowWindow(hWndAccessApp, nCmdShow)
        Err.Clear
    End If
    
    If nCmdShow = SW_SHOWMINIMIZED And loForm.Modal = True Then
        MsgBox "Cannot minimize Access with " _
                    & (loForm.Caption + " ") _
                    & "form on screen"
    ElseIf nCmdShow = SW_HIDE And loForm.PopUp <> True Then
        MsgBox "Cannot hide Access with " _
                    & (loForm.Caption + " ") _
                    & "form on screen"
    Else
        loX = apiShowWindow(hWndAccessApp, nCmdShow)
    End If
    fSetAccessWindow = (loX <> 0)
End Function

SetAccessWindow (SW_HIDE)

Option Compare Database
Option Explicit

' This code was originally written by Dev Ashish.
' It is not to be altered or distributed, except as part of an application.
' You are free to use it in any application, provided the copyright notice is left unchanged.
'
' Code Courtesy of Dev Ashish
'
Global Const SW_HIDE = 0
Global Const SW_SHOWNORMAL = 1
Global Const SW_SHOWMINIMIZED = 2
Global Const SW_SHOWMAXIMIZED = 3

[COLOR="Red"]#If VBA7 Then
    Private Declare PtrSafe Function apiShowWindow Lib "user32" Alias "ShowWindow" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long
#ElseIf Win64 Then 'need datatype LongPtr
    Private Declare PtrSafe Function apiShowWindow Lib "user32" Alias "ShowWindow" (ByVal hwnd As LongPtr, ByVal nCmdShow As LongPtr) As LongPtr
#Else '32-bit Office[/COLOR]
    Private Declare Function apiShowWindow Lib "user32" Alias "ShowWindow" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long
[COLOR="red"]#End If[/COLOR]

Function SetAccessWindow(CmdShow As Long)

'Usage Examples
'Maximize window:
' ?SetAccessWindow(SW_SHOWMAXIMIZED)
'Minimize window:
' ?SetAccessWindow(SW_SHOWMINIMIZED)
'Hide window:
' ?SetAccessWindow(SW_HIDE)
'Normal window:
' ?SetAccessWindow(SW_SHOWNORMAL)
'
    Dim loX As Long
    
    On Error Resume Next

    loX = apiShowWindow(hWndAccessApp, CmdShow)
    SetAccessWindow = (loX <> 0)

End Function

SetAccessWindow(SW_SHOWNORMAL)

SetAccessWindow(SW_SHOWMAXIMIZED)

Option Compare Database
Option Explicit
Option Base 0

'==============================
'  CONSTANTS FOR DBASE WINDOW
'==============================
Public Const SW_HIDE = 0
Public Const SW_SHOWNORMAL = 1
Public Const SW_SHOWMINIMIZED = 2
Public Const SW_SHOWMAXIMIZED = 3
 
'==========================
'  DBASE WINDOW FUNCTIONS
'==========================
#If VBA7 Then
Public Declare PtrSafe Function IsWindowVisible Lib "user32.dll" _
        (ByVal hWnd As Long) _
    As Long
Public Declare PtrSafe Function ShowWindow Lib "user32" _
        (ByVal hWnd As Long, _
        ByVal nCmdShow As Long) _
    As Long
#Else
Public Declare Function IsWindowVisible Lib "user32.dll" _
        (ByVal hwnd As Long) _
    As Long
Public Declare Function ShowWindow Lib "user32" _
        (ByVal hwnd As Long, _
        ByVal nCmdShow As Long) _
    As Long

#End If
 
'============================
' FORM MANAGEMENT FUNCTIONS
'============================
 
Public Function fAccessWindow(Optional Procedure As String, _
    Optional SwitchStatus As Boolean, Optional StatusCheck As Boolean) As Boolean
'****************************************************************************************
'* Purpose:  Controls the behavior and appearance of the Daatabase window               *
'*           residing on the form, and hence, we reduce the overall size of the FE DB.  *
'* Accepts:  Procedure -    describes the behavior requested                            *
'*           SwitchStatus - (optional) instructs the procedure to switch the current    *
'*                          status of the DB Window                                     *
'*           StatusCheck -  (optional) allows the procedure to check the current status *
'*                          of the DB window to determine whether or not to initiate a  *
'*                          change                                                      *
'****************************************************************************************
On Error GoTo EH
    Dim dwReturn As Long
    Select Case Procedure
        Case "Hide"
            dwReturn = ShowWindow(Application.hWndAccessApp, SW_HIDE)
        Case "Minimize"
            dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMINIMIZED)
        Case "Normal"
            dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWNORMAL)
        Case "Show"
            dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMAXIMIZED)
    End Select
    If SwitchStatus = True Then
        If IsWindowVisible(hWndAccessApp) = 1 Then
            dwReturn = ShowWindow(Application.hWndAccessApp, SW_HIDE)
        Else
            dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMAXIMIZED)
        End If
    End If
    If StatusCheck = True Then
        If IsWindowVisible(hWndAccessApp) = 0 Then
            fAccessWindow = False
        End If
        If IsWindowVisible(hWndAccessApp) = 1 Then
            fAccessWindow = True
        End If
    End If
    Exit Function
EH:
    MsgBox "There was an error resetting the Database Window!  " & _
        "Please contact your Database Administrator.", vbCritical, "Error!"
    Exit Function
End Function
 
Public Function RestoreForm(FormName As String)
'**********************************************************************************
'* Purpose:  Manages the database window, keep the current form on top of others. *
'* Accepts:  FormName is the name of the Form which you want to restore           *
'* Returns:  N/A                                                                  *
'*   Usage:  Add "RestoreForm Me.Form.Name" to the OnOpen event of a form         *
'**********************************************************************************
On Error GoTo EH
    fAccessWindow "Minimize", False, False
    DoCmd.SelectObject acForm, FormName
    DoCmd.Restore
    Exit Function
EH:
    MsgBox "There was an error restoring the Form.  " & _
        "Please contact your Database Administrator.", vbOKOnly, "Error!"
    Exit Function
End Function