Import file not working 32 to 64 upgrade

J

JSmothers

New member
Local time
Yesterday, 20:08
Joined
Jul 10, 2019
Messages
6
Hello, since my pc was upgraded, this code will not run. It goes directly to the "File selection was canceled." It worked fine before the upgrade but I had to put PtrSafe declarations in the following to get it it even open. Any help would be greatly appreciated on ideas to fix???



Option Explicit

Private Declare PtrSafe Function ts_apiGetOpenFileName Lib "comdlg32.dll" _
Alias "GetOpenFileNameA" (tsFN As tsFileName) As Boolean

Private Declare PtrSafe Function ts_apiGetSaveFileName Lib "comdlg32.dll" _
Alias "GetSaveFileNameA" (tsFN As tsFileName) As Boolean

Private Declare PtrSafe Function CommDlgExtendedError Lib "comdlg32.dll" () As Long



Dim strCurrProjPath As String
Dim objExcel As Object 'Excel.Application
Dim objWorkbook As Object 'Excel.Workbook
Dim objWorksheet As Object 'Worksheet
Dim strXlFileName As String 'Excel Workbook name
Dim strWorksheetName As String 'Excel Worksheet name
Dim objCell As Object 'Last used cell in column
Dim strUsedRange As String 'Used range
Dim FileName As String
Dim objDialog, boolResult

Dim strFilter As String
Dim lngFlags As Long
Dim varFileName As Variant


On Error GoTo Err_ImportSeveranceData

strFilter = "All Files (*.*)" & vbNullChar & "*.*"

lngFlags = tscFNPathMustExist Or tscFNFileMustExist Or tscFNHideReadOnly

varFileName = tsGetFileFromUser( _
fOpenFile:=True, _
strFilter:=strFilter, _
rlngflags:=lngFlags, _
strInitialDir:="C:\Windows", _
strDialogTitle:="Find File (Select The File And Click The Open Button)")
'remove the strInitialDir:="C:\Windows", _ line if you do not want the Browser to open at a specific location

If IsNull(varFileName) Or varFileName = "" Then
Debug.Print "User pressed 'Cancel'."
Beep
MsgBox "File selection was canceled.", vbInformation
Exit Sub
Else
tbFile = varFileName
End If


'Assign Path and filename of XL file to variable
strXlFileName = varFileName

'Assign Excel application to a variable
Set objExcel = CreateObject("Excel.Application")
objExcel.Visible = False 'Can be visible or not visible
objExcel.UserControl = True

'Open the Excel Workbook
Set objWorkbook = objExcel.Workbooks.Open(strXlFileName)
', Password:="gap$term"

'Assign required worksheet to a variable
With objWorkbook
Set objWorksheet = .Worksheets(1)
End With

With objWorksheet
'Assign worksheet name to a string variable
strWorksheetName = .Name

End With


'Turn off/Close in reverse order to setting/opening.
Set objCell = Nothing
Set objWorksheet = Nothing

'SaveChanges = False suppresses save message
objWorkbook.Close SaveChanges:=False
Set objWorkbook = Nothing
objExcel.Quit
Set objExcel = Nothing

'Import the worksheet
DoCmd.TransferSpreadsheet acImport, 8, "tblSeveranceData", _
strXlFileName, True, "DynamicRange"


MsgBox "Severance data imported successfully!"
 
Hi. Welcome to the forum! If you're not against it, I would recommend trying out the FileDialog Object to replace your API code.
 
Does tsGetFileFromUser() run or return a value?
Does the function need to be upgraded also?
 
Last edited:
When I DIM out the error, it states "Invalid use of Null"
 
Sorry, I get that message when I dim this out:


If IsNull(varFileName) Or varFileName = "" Then
Debug.Print "User pressed 'Cancel'."
Beep
MsgBox "File selection was canceled.", vbInformation
Exit Sub
Else
tbFile = varFileName
End If
 
Here is another piece of the code I am calling on:


Public Sub tsGetFileFromUserTest()
On Error GoTo tsGetFileFromUserTest_Err

Dim strFilter As String
Dim lngFlags As Long
Dim varFileName As Variant

' strFilter = "Access (*.mdb)" & vbNullChar & "*.mdb" _
' & vbNullChar & "All Files (*.*)" & vbNullChar & "*.*"
strFilter = "All Files (*.*)" & vbNullChar & "*.*"

lngFlags = tscFNPathMustExist Or tscFNFileMustExist Or tscFNHideReadOnly

varFileName = tsGetFileFromUser( _
fOpenFile:=True, _
strFilter:=strFilter, _
rlngflags:=lngFlags, _
strDialogTitle:="GetFileFromUser Test (Please choose a file)")

If IsNull(varFileName) Then
Debug.Print "User pressed 'Cancel'."
Else
Debug.Print varFileName
'Forms![Form1]![Text1] = varFileName
End If

If varFileName <> "" Then MsgBox "You selected the '" & varFileName & "' file.", vbInformation

tsGetFileFromUserTest_End:
On Error GoTo 0
Exit Sub

tsGetFileFromUserTest_Err:
Beep
MsgBox Err.Description, , "Error: " & Err.Number _
& " in sub basBrowseFiles.tsGetFileFromUserTest"
Resume tsGetFileFromUserTest_End

End Sub
 
JSmothers said:
Hello, since my pc was upgraded, this code will not run. It goes directly to the "File selection was canceled." It worked fine before the upgrade but I had to put PtrSafe declarations in the following to get it it even open. Any help would be greatly appreciated on ideas to fix???

Option Explicit

Private Declare PtrSafe Function ts_apiGetOpenFileName Lib "comdlg32.dll" _
Alias "GetOpenFileNameA" (tsFN As tsFileName) As Boolean

Private Declare PtrSafe Function ts_apiGetSaveFileName Lib "comdlg32.dll" _
Alias "GetSaveFileNameA" (tsFN As tsFileName) As Boolean

Private Declare PtrSafe Function CommDlgExtendedError Lib "comdlg32.dll" () As Long
Click to expand...

Just because you've added PtrSafe, it doesn't necessarily mean that an API call will run in 64-bit

I stopped using the Common Controls reference code several years ago as I couldn't get it to run in 64-bit systems.
In fact I believe that comdlg32.dll isn't installed with Windows 1 and can no longer be added as a reference
I've never used the specific CommDlgExtendedError API call that is causing your error

As DBG suggested I would use a different method such as FileDialog object
For example to browse and select a file, I use code like

Code: 
Private Sub cmdBrowse_Click()
    
On Error GoTo Err_cmdBrowse_Click

'CR 28/08/2015 - Code rewritten to ensure compatibility with 64-bit Office

' Set options for the dialog box.
    Dim F As FileDialog, strFileName As String

    Set F = Application.FileDialog(msoFileDialogFilePicker)
    F.Title = "Locate the file to be attached and click on 'Open'"
    F.AllowMultiSelect = False
    
' Clear out the current filters
    F.Filters.Clear
    
' Set the start folder
    F.InitialFileName = "c:\"
    
' Call the Open dialog routine.
    F.Show

' Return the path and file name.
    strFilename = F.SelectedItems(1)
    
    Me.txtFile = strFilename

Exit_cmdBrowse_Click:
    Exit Sub

Err_cmdBrowse_Click:
    'err=5, user clicked cancel
    If Err.Number = 5 Then Exit Sub
        
   MsgBox "Error " & err.Number & " in cmdBrowse_Click procedure : " & Err.Description
    
    Resume Exit_cmdBrowse_Click
    
End Sub

Hope that helps
 
try this in a new module, I've converted it to x64 and it's working just fine for me:
Option Compare Database
Option Explicit

'Dim strFilter As String
'Dim strInputFileName As String
'
'strFilter = ahtAddFilterItem(strFilter, "Excel Files (*.XLS)", "*.XLS")
'strInputFileName = ahtCommonFileOpenSave( _
' Filter:=strFilter, OpenFile:=True, _
' DialogTitle:="Please select an input file...", _
' Flags:=ahtOFN_HIDEREADONLY)
'
'Note that in order to call the Save As dialog box, you can use the same wrapper function by just setting the OpenFile option as False. For example,
'
'Ask for SaveFileName
'strFilter = ahtAddFilterItem(myStrFilter, "Excel Files (*.xls)", "*.xls")
'strSaveFileName = ahtCommonFileOpenSave( _
' OpenFile:=False, _
' Filter:=strFilter, _
' Flags:=ahtOFN_OVERWRITEPROMPT Or ahtOFN_READONLY)

'***************** Code Start **************
'This code was originally written by Ken Getz. It is not to be altered or distributed, except as part of an application.
'You are free to use it in any application, provided the copyright notice is left unchanged.
' Code courtesy of: Microsoft Access 95 How-To Ken Getz and Paul Litwin Waite Group Press, 1996
'See :- http://www.mvps.org/access/api/api0001.htm for more information

Type tagOPENFILENAME
lStructSize As Long
hWndOwner As LongPtr
hInstance As LongPtr
strFilter As String
strCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
strFile As String
nMaxFile As Long
strFileTitle As String
nMaxFileTitle As Long
strInitialDir As String
strTitle As String
Flags As Long
nFileOffset As Integer
nFileExtension As Integer
strDefExt As String
lCustData As LongPtr
lpfnHook As LongPtr
lpTemplateName As String
End Type

Declare PtrSafe Function aht_apiGetOpenFileName Lib "comdlg32.dll" Alias "GetOpenFileNameA" (ofn As tagOPENFILENAME) As Boolean
Declare PtrSafe Function aht_apiGetSaveFileName Lib "comdlg32.dll" Alias "GetSaveFileNameA" (ofn As tagOPENFILENAME) As Boolean
Declare PtrSafe Function CommDlgExtendedError Lib "comdlg32.dll" () As Long

Global Const ahtOFN_READONLY = &H1
Global Const ahtOFN_OVERWRITEPROMPT = &H2
Global Const ahtOFN_HIDEREADONLY = &H4
Global Const ahtOFN_NOCHANGEDIR = &H8
Global Const ahtOFN_SHOWHELP = &H10
Global Const ahtOFN_NOVALIDATE = &H100
Global Const ahtOFN_ALLOWMULTISELECT = &H200
Global Const ahtOFN_EXTENSIONDIFFERENT = &H400
Global Const ahtOFN_PATHMUSTEXIST = &H800
Global Const ahtOFN_FILEMUSTEXIST = &H1000
Global Const ahtOFN_CREATEPROMPT = &H2000
Global Const ahtOFN_SHAREAWARE = &H4000
Global Const ahtOFN_NOREADONLYRETURN = &H8000
Global Const ahtOFN_NOTESTFILECREATE = &H10000
Global Const ahtOFN_NONETWORKBUTTON = &H20000
Global Const ahtOFN_NOLONGNAMES = &H40000
Global Const ahtOFN_EXPLORER = &H80000
Global Const ahtOFN_NODEREFERENCELINKS = &H100000
Global Const ahtOFN_LONGNAMES = &H200000

Function ahtCommonFileOpenSave( _
Optional ByRef Flags As Variant, _
Optional ByVal InitialDir As Variant, _
Optional ByVal Filter As Variant, _
Optional ByVal FilterIndex As Variant, _
Optional ByVal DefaultExt As Variant, _
Optional ByVal Filename As Variant, _
Optional ByVal DialogTitle As Variant, _
Optional ByVal hWnd As Variant, _
Optional ByVal OpenFile As Variant) As Variant

'This is the entry point you'll use to call the common file open/save dialog.
'The parameters are listed below, and all are optional.
'
' In:
' Flags: one or more of the ahtOFN_* constants, OR'd together.
' InitialDir: the directory in which to first look
' Filter: a set of file filters, set up by calling
' AddFilterItem. See examples.
' FilterIndex: 1-based integer indicating which filter set to use, by default (1 if unspecified)
' DefaultExt: Extension to use if the user doesn't enter one. Only useful on file saves.
' FileName: Default value for the file name text box.
' DialogTitle: Title for the dialog.
' hWnd: parent window handle
' OpenFile: Boolean(True=Open File/False=Save As)
' Out:
' Return Value: Either Null or the selected filename

Dim ofn As tagOPENFILENAME
Dim strFileName As String
Dim strFileTitle As String
Dim fResult As Boolean
' Give the dialog a caption title.

If IsMissing(InitialDir) Then InitialDir = CurDir
If IsMissing(Filter) Then Filter = ""
If IsMissing(FilterIndex) Then FilterIndex = 1
If IsMissing(Flags) Then Flags = 0&
If IsMissing(DefaultExt) Then DefaultExt = ""
If IsMissing(Filename) Then Filename = ""
If IsMissing(DialogTitle) Then DialogTitle = ""
If IsMissing(hWnd) Then hWnd = Application.hWndAccessApp
If IsMissing(OpenFile) Then OpenFile = True
' Allocate string space for the returned strings.
strFileName = Left(Filename & String(256, 0), 256)
strFileTitle = String(256, 0)
' Set up the data structure before you call the function
With ofn
.lStructSize = LenB(ofn)
.hWndOwner = hWnd
.strFilter = Filter
.nFilterIndex = FilterIndex
.strFile = strFileName
.nMaxFile = Len(strFileName)
.strFileTitle = strFileTitle
.nMaxFileTitle = Len(strFileTitle)
.strTitle = DialogTitle
.Flags = Flags
.strDefExt = DefaultExt
.strInitialDir = InitialDir
' Didn't think most people would want to deal with
' these options.
.hInstance = 0
'.strCustomFilter = ""
'.nMaxCustFilter = 0
.lpfnHook = 0
'New for NT 4.0
.strCustomFilter = String(255, 0)
.nMaxCustFilter = 255
End With
' This will pass the desired data structure to the
' Windows API, which will in turn it uses to display
' the Open/Save As Dialog.
If OpenFile Then
fResult = aht_apiGetOpenFileName(ofn)
Else
fResult = aht_apiGetSaveFileName(ofn)
End If

' The function call filled in the strFileTitle member
' of the structure. You'll have to write special code
' to retrieve that if you're interested.
If fResult Then
' You might care to check the Flags member of the
' structure to get information about the chosen file.
' In this example, if you bothered to pass in a
' value for Flags, we'll fill it in with the outgoing
' Flags value.
If Not IsMissing(Flags) Then Flags = ofn.Flags
ahtCommonFileOpenSave = TrimNull(ofn.strFile)
Else
ahtCommonFileOpenSave = vbNullString
End If

End Function

Function ahtAddFilterItem(strFilter As String, strDescription As String, Optional varItem As Variant) As String

' Tack a new chunk onto the file filter.
' That is, take the old value, stick onto it the description,
' (like "Databases"), a null character, the skeleton
' (like "*.mdb;*.mda") and a final null character.

If IsMissing(varItem) Then varItem = "*.*"
ahtAddFilterItem = strFilter & strDescription & vbNullChar & varItem & vbNullChar

End Function

Function TrimNull(ByVal StrItem As String) As String

Dim intPos As Integer

intPos = InStr(StrItem, vbNullChar)
If intPos > 0 Then
TrimNull = Left(StrItem, intPos - 1)
Else
TrimNull = StrItem
End If

End Function
Click to expand...

and call the function like:
strInputFileName = ahtCommonFileOpenSave( _
Filter:=strFilter, OpenFile:=True, _
DialogTitle:="Please select an input file...", _
Flags:=ahtOFN_HIDEREADONLY)
Click to expand...
or:
strInputFileName = ahtCommonFileOpenSave(OpenFile:=True, InitialDir:="C:", Filter:=vFilter, FilterIndex:=1, DialogTitle:="Locate Holiday Data File", Flags:=4 + 4096)
Click to expand...

hope it helps,

Cheers,
Margarit
 
Margarit, you are a life saver!! Here is my final code to call on your procedure:
Thanks so much for your help!!



Public Sub ImportSeveranceData()
Dim strCurrProjPath As String
Dim objExcel As Object 'Excel.Application
Dim objWorkbook As Object 'Excel.Workbook
Dim objWorksheet As Object 'Worksheet
Dim strXlFileName As String 'Excel Workbook name
Dim strWorksheetName As String 'Excel Worksheet name
Dim objCell As Object 'Last used cell in column
Dim strUsedRange As String 'Used range
Dim Filename As String
Dim objDialog, boolResult
Dim strInputFileName As String

Dim strFilter As String
Dim lngFlags As Long
Dim varFileName As Variant



On Error GoTo Err_ImportSeveranceData

varFileName = ahtCommonFileOpenSave( _
Filter:=strFilter, OpenFile:=True, _
DialogTitle:="Please select an input file...", _
Flags:=ahtOFN_HIDEREADONLY)


If IsNull(varFileName) Or varFileName = "" Then
Debug.Print "User pressed 'Cancel'."
Beep
MsgBox "File selection was canceled.", vbInformation
Exit Sub
Else
tbFile = varFileName
End If


'Assign Path and filename of XL file to variable
strXlFileName = varFileName


'Assign Excel application to a variable
Set objExcel = CreateObject("Excel.Application")
objExcel.Visible = False 'Can be visible or not visible
objExcel.UserControl = True

'Open the Excel Workbook
Set objWorkbook = objExcel.Workbooks.Open(strXlFileName)
', Password:="gap$term"

'Assign required worksheet to a variable
With objWorkbook
Set objWorksheet = .Worksheets(1)
End With

With objWorksheet
'Assign worksheet name to a string variable
strWorksheetName = .Name

End With


'Turn off/Close in reverse order to setting/opening.
Set objCell = Nothing
Set objWorksheet = Nothing

'SaveChanges = False suppresses save message
objWorkbook.Close SaveChanges:=False
Set objWorkbook = Nothing
objExcel.Quit
Set objExcel = Nothing

'Import the worksheet
DoCmd.TransferSpreadsheet acImport, 8, "tblSeveranceData", _
strXlFileName, True, "DynamicRange"


MsgBox "Severance data imported successfully!"


Exit_ImportSeveranceData:
Exit Sub

Err_ImportSeveranceData:
MsgBox Err.Description
Resume Exit_ImportSeveranceData

End Sub
 
I'm glad it worked.. happy to help.

Cheers,
Margarit
 
Jsmothers
Margarit (riti90)has done a fantastic job with the conversion and thoroughly deserves the thanks given by you.
In fact she is becoming quite a specialist in doing such conversions.

If any of your users will still be running 32-bit Access, you may need conditional compilation to ensure the code runs in both 'bitnesses'.
For that reason, my recommendation is to only use API calls where these provide functionality not available using native code. As already mentioned, in this case, I'm fairly sure that FileDialog would have worked perfectly with no need for any API calls or conversions.

Good luck with the rest of your project
 
isladogs said:
If any of your users will still be running 32-bit Access, you may need conditional compilation to ensure the code runs in both 'bitnesses'.
Click to expand...
Only if they still run a version of Access (Acc2007 or earlier) which is out of support for multiple years now!
 
Hi Phillip
Absolutely. That's why I said 'may need'
 
isladogs said:
Jsmothers
If any of your users will still be running 32-bit Access, you may need conditional compilation to ensure the code runs in both 'bitnesses'.
Click to expand...

Probably will need to use something like this:
Code: 
Option Compare Database
Option Explicit

'Dim strFilter As String
'Dim strInputFileName As String
'
'strFilter = ahtAddFilterItem(strFilter, "Excel Files (*.XLS)", "*.XLS")
'strInputFileName = ahtCommonFileOpenSave( _
' Filter:=strFilter, OpenFile:=True, _
' DialogTitle:="Please select an input file...", _
' Flags:=ahtOFN_HIDEREADONLY)
'
'Note that in order to call the Save As dialog box, you can use the same wrapper function by just setting the OpenFile option as False. For example,
'
'Ask for SaveFileName
'strFilter = ahtAddFilterItem(myStrFilter, "Excel Files (*.xls)", "*.xls")
'strSaveFileName = ahtCommonFileOpenSave( _
' OpenFile:=False, _
' Filter:=strFilter, _
' Flags:=ahtOFN_OVERWRITEPROMPT Or ahtOFN_READONLY)

'***************** Code Start **************
'This code was originally written by Ken Getz. It is not to be altered or distributed, except as part of an application.
'You are free to use it in any application, provided the copyright notice is left unchanged.
' Code courtesy of: Microsoft Access 95 How-To Ken Getz and Paul Litwin Waite Group Press, 1996
'See :- http://www.mvps.org/access/api/api0001.htm for more information

[COLOR="Red"]#If VBA7 Then[/COLOR]

Type tagOPENFILENAME
lStructSize As Long
hWndOwner As Long[COLOR="red"]Ptr[/COLOR]
hInstance As Long[COLOR="red"]Ptr[/COLOR]
strFilter As String
strCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
strFile As String
nMaxFile As Long
strFileTitle As String
nMaxFileTitle As Long
strInitialDir As String
strTitle As String
Flags As Long
nFileOffset As Integer
nFileExtension As Integer
strDefExt As String
lCustData As Long[COLOR="red"]Ptr[/COLOR]
lpfnHook As Long[COLOR="red"]Ptr[/COLOR]
lpTemplateName As String
End Type

Declare [COLOR="red"]PtrSafe [/COLOR]Function aht_apiGetOpenFileName Lib "comdlg32.dll" Alias "GetOpenFileNameA" (ofn As tagOPENFILENAME) As Boolean
Declare [COLOR="red"]PtrSafe [/COLOR]Function aht_apiGetSaveFileName Lib "comdlg32.dll" Alias "GetSaveFileNameA" (ofn As tagOPENFILENAME) As Boolean
Declare [COLOR="red"]PtrSafe [/COLOR]Function CommDlgExtendedError Lib "comdlg32.dll" () As Long

[COLOR="Red"]#Else[/COLOR]

Type tagOPENFILENAME
lStructSize As Long
hWndOwner As Long
hInstance As Long
strFilter As String
strCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
strFile As String
nMaxFile As Long
strFileTitle As String
nMaxFileTitle As Long
strInitialDir As String
strTitle As String
Flags As Long
nFileOffset As Integer
nFileExtension As Integer
strDefExt As String
lCustData As Long
lpfnHook As Long
lpTemplateName As String
End Type

Declare Function aht_apiGetOpenFileName Lib "comdlg32.dll" Alias "GetOpenFileNameA" (ofn As tagOPENFILENAME) As Boolean
Declare Function aht_apiGetSaveFileName Lib "comdlg32.dll" Alias "GetSaveFileNameA" (ofn As tagOPENFILENAME) As Boolean
Declare Function CommDlgExtendedError Lib "comdlg32.dll" () As Long

[COLOR="red"]#End If[/COLOR]


Global Const ahtOFN_READONLY = &H1
Global Const ahtOFN_OVERWRITEPROMPT = &H2
Global Const ahtOFN_HIDEREADONLY = &H4
Global Const ahtOFN_NOCHANGEDIR = &H8
Global Const ahtOFN_SHOWHELP = &H10
Global Const ahtOFN_NOVALIDATE = &H100
Global Const ahtOFN_ALLOWMULTISELECT = &H200
Global Const ahtOFN_EXTENSIONDIFFERENT = &H400
Global Const ahtOFN_PATHMUSTEXIST = &H800
Global Const ahtOFN_FILEMUSTEXIST = &H1000
Global Const ahtOFN_CREATEPROMPT = &H2000
Global Const ahtOFN_SHAREAWARE = &H4000
Global Const ahtOFN_NOREADONLYRETURN = &H8000
Global Const ahtOFN_NOTESTFILECREATE = &H10000
Global Const ahtOFN_NONETWORKBUTTON = &H20000
Global Const ahtOFN_NOLONGNAMES = &H40000
Global Const ahtOFN_EXPLORER = &H80000
Global Const ahtOFN_NODEREFERENCELINKS = &H100000
Global Const ahtOFN_LONGNAMES = &H200000

Function ahtCommonFileOpenSave( _
Optional ByRef Flags As Variant, _
Optional ByVal InitialDir As Variant, _
Optional ByVal Filter As Variant, _
Optional ByVal FilterIndex As Variant, _
Optional ByVal DefaultExt As Variant, _
Optional ByVal Filename As Variant, _
Optional ByVal DialogTitle As Variant, _
Optional ByVal hWnd As Variant, _
Optional ByVal OpenFile As Variant) As Variant

'This is the entry point you'll use to call the common file open/save dialog.
'The parameters are listed below, and all are optional.
'
' In:
' Flags: one or more of the ahtOFN_* constants, OR'd together.
' InitialDir: the directory in which to first look
' Filter: a set of file filters, set up by calling
' AddFilterItem. See examples.
' FilterIndex: 1-based integer indicating which filter set to use, by default (1 if unspecified)
' DefaultExt: Extension to use if the user doesn't enter one. Only useful on file saves.
' FileName: Default value for the file name text box.
' DialogTitle: Title for the dialog.
' hWnd: parent window handle
' OpenFile: Boolean(True=Open File/False=Save As)
' Out:
' Return Value: Either Null or the selected filename

Dim ofn As tagOPENFILENAME
Dim strFileName As String
Dim strFileTitle As String
Dim fResult As Boolean
' Give the dialog a caption title.

If IsMissing(InitialDir) Then InitialDir = CurDir
If IsMissing(Filter) Then Filter = ""
If IsMissing(FilterIndex) Then FilterIndex = 1
If IsMissing(Flags) Then Flags = 0&
If IsMissing(DefaultExt) Then DefaultExt = ""
If IsMissing(Filename) Then Filename = ""
If IsMissing(DialogTitle) Then DialogTitle = ""
If IsMissing(hWnd) Then hWnd = Application.hWndAccessApp
If IsMissing(OpenFile) Then OpenFile = True
' Allocate string space for the returned strings.
strFileName = Left(Filename & String(256, 0), 256)
strFileTitle = String(256, 0)
' Set up the data structure before you call the function
[COLOR="red"]#if VBA7[/COLOR]
With ofn
.lStructSize = Len[COLOR="red"]B[/COLOR](ofn)
.hWndOwner = hWnd
.strFilter = Filter
.nFilterIndex = FilterIndex
.strFile = strFileName
.nMaxFile = Len(strFileName)
.strFileTitle = strFileTitle
.nMaxFileTitle = Len(strFileTitle)
.strTitle = DialogTitle
.Flags = Flags
.strDefExt = DefaultExt
.strInitialDir = InitialDir
' Didn't think most people would want to deal with
' these options.
.hInstance = 0
'.strCustomFilter = ""
'.nMaxCustFilter = 0
.lpfnHook = 0
'New for NT 4.0
.strCustomFilter = String(255, 0)
.nMaxCustFilter = 255
End With

[COLOR="red"]#Else[/COLOR]

With ofn
.lStructSize = Len(ofn)
.hWndOwner = hWnd
.strFilter = Filter
.nFilterIndex = FilterIndex
.strFile = strFileName
.nMaxFile = Len(strFileName)
.strFileTitle = strFileTitle
.nMaxFileTitle = Len(strFileTitle)
.strTitle = DialogTitle
.Flags = Flags
.strDefExt = DefaultExt
.strInitialDir = InitialDir
' Didn't think most people would want to deal with
' these options.
.hInstance = 0
'.strCustomFilter = ""
'.nMaxCustFilter = 0
.lpfnHook = 0
'New for NT 4.0
.strCustomFilter = String(255, 0)
.nMaxCustFilter = 255
End With

[COLOR="red"]#End If[/COLOR]

' This will pass the desired data structure to the
' Windows API, which will in turn it uses to display
' the Open/Save As Dialog.
If OpenFile Then
fResult = aht_apiGetOpenFileName(ofn)
Else
fResult = aht_apiGetSaveFileName(ofn)
End If

' The function call filled in the strFileTitle member
' of the structure. You'll have to write special code
' to retrieve that if you're interested.
If fResult Then
' You might care to check the Flags member of the
' structure to get information about the chosen file.
' In this example, if you bothered to pass in a
' value for Flags, we'll fill it in with the outgoing
' Flags value.
If Not IsMissing(Flags) Then Flags = ofn.Flags
ahtCommonFileOpenSave = TrimNull(ofn.strFile)
Else
ahtCommonFileOpenSave = vbNullString
End If

End Function

Function ahtAddFilterItem(strFilter As String, strDescription As String, Optional varItem As Variant) As String

' Tack a new chunk onto the file filter.
' That is, take the old value, stick onto it the description,
' (like "Databases"), a null character, the skeleton
' (like "*.mdb;*.mda") and a final null character.

If IsMissing(varItem) Then varItem = "*.*"
ahtAddFilterItem = strFilter & strDescription & vbNullChar & varItem & vbNullChar

End Function

Function TrimNull(ByVal StrItem As String) As String

Dim intPos As Integer

intPos = InStr(StrItem, vbNullChar)
If intPos > 0 Then
TrimNull = Left(StrItem, intPos - 1)
Else
TrimNull = StrItem
End If

End Function

Regards,
Margarit
 
You must log in or register to reply here.

Similar threads

LanaR
Further adventures in migrating to 64 bit
Replies
4
Views
729
LanaR
LanaR
J
Adjusting to work in VBA 64 bit
Replies
5
Views
1,088
jet8510
J
AOB
Solved Making an old 32-bit MDB file 64-bit-compilable
Replies
5
Views
1,441
sonic8
S
5
Solved Can't find what's trimming my string to 255 characters
Replies
7
Views
1,209
561414
5
G
OpenFileName 64-Bit
Replies
7
Views
2,572
theDBguy
theDBguy

Users who are viewing this thread

Total: 1 (members: 0, guests: 1)
Back
Top Bottom