On Deactivate (1 Viewer)

[bconner]

I have a subform and I have checks I want to do when the user clicks anywhere off of the subform and I am using OnDeactivate.
The problem is the OnDeactivate won't trigger when I click on the parent form or another subform.
I even tried OnlostFocus and it doesn't work either.

Private Sub Form_Deactivate()


' Check to make sure Outcomes is populated
If (IsNull(cmb_Action_Outcome) = True And IsNull(cmb_Action_Taken) = False) Then
   MsgBox "Action Outcome is a required field, please choose an Action Outcome."
   cmb_Action_Outcome.SetFocus
   Exit Sub
End If
' Check to make sure the action taken is populated
If (IsNull(cmb_Action_Outcome) = False And IsNull(cmb_Action_Taken) = True) Then
   MsgBox "Action Taken is a required field, please choose an Action Taken."
   cmb_Action_Outcome = Null
   cmb_Action_Taken.SetFocus
   Exit Sub
End If

End Sub

 

[June7]

You want to do some checks even if data has not been entered/edited?

 

[Mike Krailo]

The problem is the OnDeactivate won't trigger when I click on the parent form or another subform.
I even tried OnlostFocus and it doesn't work either.

I'll bet it works if you put this in the subforms before update event.

Private Sub Form_BeforeUpdate(Cancel As Integer)
   ' Check to make sure Outcomes is populated
   If (IsNull(cmb_Action_Outcome) = True And IsNull(cmb_Action_Taken) = False) Then
      MsgBox "Action Outcome is a required field, please choose an Action Outcome."
      Cancel = True
      cmb_Action_Outcome.SetFocus
      Exit Sub
   End If
   ' Check to make sure the action taken is populated
   If (IsNull(cmb_Action_Outcome) = False And IsNull(cmb_Action_Taken) = True) Then
      MsgBox "Action Taken is a required field, please choose an Action Taken."
      Cancel = True
      cmb_Action_Taken.SetFocus
      Exit Sub
   End If
End Sub

 

[The_Doc_Man]

Not surprised that a Form_LostFocus doesn't fire very often, since a form can ONLY have focus if NONE of its controls are active (or are not capable of gaining focus in the first place.) A control_LostFocus should work OK, though.

 

[moke123]

If (IsNull(cmb_Action_Outcome) = True And IsNull(cmb_Action_Taken) = False) Then

If (IsNull(cmb_Action_Outcome) = False And IsNull(cmb_Action_Taken) = True) Then

Do you need the "And" portion? What if both are null?

You can also use a public function to validate your forms.
In the Before update event

Cancel = InvalidFrm(me)

In the tag property of the controls to check put V8
The control must have a label (used in a msgbox) but it can be hidden if desired.
Fires a message box listing missing info and highlights controls in red.

Public Function InValidFrm(frm As Form) As Boolean
    'returns True if missing data  ie. Cancel = InvalidFrm
    'control requires a label, can be hidden if desired
    'Place V8 in tag of control to test for missing info

    Dim ctl As Control, ctlSub As Control
    Dim msg As String
      
    For Each ctl In frm.Controls
    
        If InStr(1, ctl.Tag, "V8") Then

            If Nz(ctl.Value, "") = "" Then
                InValidFrm = True
                msg = msg & Space(5) & "* " & ctl.Controls(0).Caption & vbNewLine
                ctl.BorderColor = vbRed
            Else
                ctl.BorderColor = vbBlack
            End If
            
        ElseIf TypeName(ctl) = "Subform" Then

            For Each ctlSub In ctl.Form.Controls
                
                If InStr(1, ctlSub.Tag, "V8") Then

                    If Nz(ctlSub.Value, "") = "" Then
                        InValidFrm = True
                        msg = msg & Space(5) & "* " & ctlSub.Controls(0).Caption & vbNewLine
                        ctlSub.BorderColor = vbRed
                    Else
                        ctlSub.BorderColor = vbBlack

                    End If
            
                End If

            Next

        End If
      
    Next
    
    If InValidFrm Then
        MsgBox Space(6) & "Please Complete The " & vbNewLine & "Following Required Fields:" & vbNewLine & vbNewLine & msg, vbExclamation, "Missing Info!"
    End If
    
End Function

 

[Pat Hartman]

I have a subform and I have checks I want to do when the user clicks anywhere off of the subform

As @Mike Krailo alluded - if you are trying to validate data, you MUST do it in the correct event in order for it to be effective.

You might benefit from viewing these videos and playing with the database that is used to show form and control events

Bad Data is Bad for Business #1 and #2

I just added #2 --- that link is further down. It is much shorter than #1. I also added a copy of the database I used for the video. Enjoy:) I created a database to help people to understand how and why to use the Form's BeforeUpdate event to validate data. @Uncle Gizmo and I made a...

www.access-programmers.co.uk

 

[prabha_friend]

Child.OnExit

 

[prabha_friend]

Please mark the thread "Solved" if you have found the solution...