Public Sub GetQueries4()
'*******************************************
'Name: GetQueries4 (Function)
'Purpose: Creates tblQueries4 and populates
' with query record source info.
'Coded by: raskew
'Inputs: From debug (immediate) window
' Call GetQueries4
'Outputs: tblQueries4
'*******************************************
Dim db As Database
Dim rs As Recordset
Dim rs2 As Recordset
Dim tName As String, tsource As String
Dim n As Integer, i As Integer, fcount As Integer
Dim x As Integer, z As Integer
Dim strSQL As String
Set db = CurrentDb
On Error Resume Next
tName = "tblQueries4"
'Does table "tblQueries4" exist? If true, delete it;
db.Execute "DROP TABLE " & tName & ";"
'Create new tblTable
db.Execute "CREATE TABLE tblQueries4(ObjectID LONG, " _
& " Type TEXT (55), Object TEXT (55), " _
& " RecordSource TEXT (55));"
strSQL = "SELECT A.Name, B.Name1" _
& " FROM MSysObjects AS A, MSysQueries AS B" _
& " WHERE (((A.Id)=[B].[ObjectID]) AND" _
& " ((B.Expression) Is Null) AND" _
& " ((Left([Name],1))<>'~') AND ((Left([Name1],1))<>'['))" _
& " ORDER BY A.Name;"
Set rs = db.OpenRecordset(strSQL)
Set rs2 = db.OpenRecordset("tblQueries4")
rs.MoveLast
n = rs.RecordCount
rs.MoveFirst
For i = 0 To n - 1
tName = rs!Name
rs2.AddNew
With rs2
!ObjectID = 2
!Type = "Query"
!Object = tName
!RecordSource = rs!Name1
.Update
End With
rs.MoveNext
Next i
rs.Close
rs2.Close
db.Close
Set db = Nothing
End Sub