Public Sub InitializeSpan()
Set FSO = New FileSystemObject
SpanFolders GetDefaultFolderFullName, 0
Set FSO = Nothing
End Sub
'---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
'************************************************************************ Span Folders *********************************************************************************
'---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
Private Sub SpanFolders(SourceFolderName As String, Optional ByVal FolderLevel = 0)
' lists information about the files in SourceFolder
' example: ListFilesInFolder "C:\FolderName\", True
'Dim FSO As Object 'Scripting.FileSystemObject
Dim SourceFolder As Scripting.Folder 'Scripting.Folder
Dim SubFolder As Scripting.Folder 'Scripting.Folder
Dim FileItem As Scripting.file 'Scripting.File
Dim ParentID As Long
Dim strAddress As String
Dim strDisplayText As String
FolderLevel = FolderLevel + 1
Set SourceFolder = FSO.GetFolder(SourceFolderName)
ParentID = GetParentID(SourceFolder.Name)
For Each SubFolder In SourceFolder.SubFolders
LogFilesFolders SubFolder.Name, SubFolder.Path, SubFolder.Type, ParentID, fft_Folder, FolderLevel
SpanFolders SubFolder.Path, FolderLevel
Next SubFolder
For Each FileItem In SourceFolder.Files
LogFilesFolders FileItem.Name, FileItem.Path, FileItem.Type, ParentID, fft_File, FolderLevel
Next FileItem
Set FileItem = Nothing
Set SourceFolder = Nothing
End Sub
'---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
'************************************************************************ Wrapper Functions *********************************************************************************
'---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
Public Function GetDefaultFolderPath()
'For Demo use the current project path
'If not you would read from the applications table
GetDefaultFolderPath = CurrentProject.Path
End Function
Public Function GetDefaultFolderName()
GetDefaultFolderName = DLookup("defaultFolderName", "tblApplicationSettings")
End Function
Public Function GetDefaultFolderFullName()
GetDefaultFolderFullName = GetDefaultFolderPath & "\" & GetDefaultFolderName
End Function
Public Function GetParentID(ByVal ParentName As String) As Long
GetParentID = Nz(DLookup("FolderFileID", "tblFoldersFiles", "FolderFileName = " & CSql(ParentName)), 0)
End Function
'---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
'************************************************************************ Logging Functions *********************************************************************************
'---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
Private Sub LogFilesFolders(ItemName As String, ItemFullName As String, ItemType As String, ParentID As Long, FolderOrFile As FileFolderType, FolderLevel)
Dim TheFields As String
Dim strFolderOrFile As String
Const TableName = "tblFoldersFiles"
TheFields = insertFields("FolderFileName", "FolderFileFullName", "FolderOrFile", "ParentFolderID", "FileType", "FolderLevel")
Select Case FolderOrFile
Case fft_Folder
strFolderOrFile = "Folder"
Case fft_File
strFolderOrFile = "File"
End Select
ParamInsert TableName, TheFields, ItemName, ItemFullName, strFolderOrFile, ParentID, ItemType, FolderLevel
End Sub
